path: root/rhimport-fl

#!/usr/bin/perl -w
#
#
#  rhimport
#
#  Copyright (C) 2016 Christian Pointner <equinox@helsinki.at>
#
#  This file is part of rhimport.
#
#  rhimport is free software: you can redistribute it and/or modify
#  it under the terms of the GNU General Public License as published by
#  the Free Software Foundation, either version 3 of the License, or
#  any later version.
#
#  rhimport is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.
#
#  You should have received a copy of the GNU General Public License
#  along with rhimport. If not, see <http://www.gnu.org/licenses/>.
#

use strict;
use DBI;
use Date::Calc;
use DateTime;
use DateTime::Format::ISO8601;
use XML::Feed;
use XML::Feed::Entry;
use XML::Feed::Content;
use XML::Feed::Enclosure;
use URI::URL;
use IO::Handle;
use IPC::Open3;
use HTML::Entities;

use lib '/usr/local/share/rhimport/';
use rhimport;

my $DBHOST = "airplay";
my $DBUSER = "rivendell";
my $DBPW = "lldriven";
my $DB = "rivendell";

my $STAT_FILE = $ENV{'HOME'} . "/rhautoimport-fl.stat";
my $LAST_FILE = $ENV{'HOME'} . "/rhautoimport-fl.last";
my $RSS_URL = "https://cba.fro.at/series/frequenz-leitwolf/feed?c=Kfs2IoV2Wmd";
$XML::Feed::MULTIPLE_ENCLOSURES=1;
my $PV_ID = '569';
my $LAST_RUN = 0;

binmode(STDIN, ":utf8");
binmode(STDOUT, ":utf8");
binmode(STDERR, ":utf8");

my $curweek = rhimport::get_rd_week();

if($curweek == 1 || $curweek == 3) {
  if($#ARGV >= 0 && $ARGV[0] eq 'last') {
    print "!!!This is the last attempt, there won't be a retry on error!!!\n";
    $LAST_RUN = 1;
  }
}

my $user = `/usr/bin/id -un`;
$user =~ s/\n//;
my $group = "leitwolf";

my $dbh = DBI->connect("DBI:mysql:$DB:$DBHOST","$DBUSER","$DBPW") or die "Database Error: $DBI::errstr";
my @allowed_dbs = rhimport::get_dropboxes($dbh, $user, $group);

if(scalar(@allowed_dbs) != 1) {
  print "found more or less than one Dropbox for this group?!\n";
  $dbh->disconnect();
  exit 1;
}
my $dropbox = $allowed_dbs[0]->{'PATH'};
my $to_cart = $allowed_dbs[0]->{'TO_CART'};

my @today = Date::Calc::Today();
my @import_date = Date::Calc::Standard_to_Business(@today);
$import_date[2] = 6;
@import_date = Date::Calc::Business_to_Standard(@import_date);

my $dow = Date::Calc::Day_of_Week(@today);
if($curweek == 1 || $curweek == 3) {
  if($dow > 6) {
    @import_date = Date::Calc::Add_Delta_Days(@import_date, 14);
  }
} else {
  @import_date = Date::Calc::Add_Delta_Days(@import_date, 7);
}
my $last_broadcast = DateTime->from_epoch(epoch => 0);
my $last_broadcast_str = `cat $LAST_FILE`;
chomp($last_broadcast_str);
if(defined($last_broadcast_str) && $last_broadcast_str ne "") {
  $last_broadcast = DateTime::Format::ISO8601->parse_datetime($last_broadcast_str);
}

print "today: " . Date::Calc::Date_to_Text(@today) . " (Week: " . $curweek . ")\n";
print "day of next Radio Helsinki broadcast: " . Date::Calc::Date_to_Text(@import_date) . "\n";
print "Last broadcast was on: " . $last_broadcast . "\n\n";

my $id = sprintf("%04d-%02d-%02d", @import_date);

my $current_stat = `cat $STAT_FILE`;
my ($current_id, $current_file) = $current_stat =~ m/^(.*)\n(.*)/;
if($current_id eq $id) {
  print "Already downloaded current file\n";
  $dbh->disconnect();
  exit 0;
}

print "looking for file after $last_broadcast in RSS Feed\n";
print " -> $RSS_URL\n";

my $feed = rhimport::fetch_parse_rss($RSS_URL)
  or die "Error fetching feed: " . XML::Feed->errstr;

my $shows_left = -1;
my $out_file = "";
my $url = "";
my $this_broadcast = $last_broadcast;
my $i = 0;
for my $entry ($feed->entries) {
  $i++;
  next unless $entry->enclosure;

  my $issued = $entry->issued;
  next unless (defined $issued);
  my $idt = DateTime::Format::ISO8601->parse_datetime($issued);

  my $diff = $idt->subtract_datetime_absolute($last_broadcast);
  last if($diff->is_zero || $diff->is_negative);

  $shows_left++;
  my $j = 0;
  for my $enclosure($entry->enclosure) {
    $j++;
    if($enclosure->type eq "audio/mpeg" || $enclosure->type eq "audio/ogg") {
      print "$i/$j: (" . $enclosure->type . ", " . $enclosure->length . ") "  . $enclosure->url . "\n";
      my $fetchurl = $enclosure->url;
      if($fetchurl =~ /^(.*)_cut(\.[^\.]+)$/) {
        $fetchurl = $1 . $2;
      }

      $url = new URI::URL($fetchurl);
      my @path = $url->path_components;
      $out_file = $path[-1];
      if(!rhimport::check_file_extension($out_file)) {
        print "\n\nThe extension of the matching file '". $out_file . "' seems to be wrong - manual import necessary!!!\n";
        $dbh->disconnect();
        exit 1;
      }

      $this_broadcast = $idt;
      last;
    }
  }
}
print " --> #" . $this_broadcast . ": downloading " . $url . " .. ";
my $file = "/tmp/" . $out_file;
system("wget", "--quiet", "--no-check-certificate", $url, "-O", $file);
if( $! != 0) {
  die "wget returned with error: " . $!;
}
print "ok\n";


if($file eq "" || !(-e "$file")) {
  print "No Entry for $last_broadcast (there are no new shows available) or download error - ";
  if($LAST_RUN) {
    print "giving up, manual import necessary!!!\n";
  } else {
    print "will retry later\n";
  }
  exit 1;
}

if($shows_left <= 0) {
  print "\n\n ****** There are *no* shows remaining! ******\n\n";
} elsif($shows_left < 4) {
  print "\n\n ** There are only $shows_left shows remaining! **\n\n";
} else {
  print "\n\nThere are $shows_left shows remaining\n\n";
}

print "will import $file to dropbox $dropbox (cart=$to_cart)\n";

my $error_cb = sub {
  my ($text) = @_;

  print "\n$text";
  return 0;
};

rhimport::check_key_file() or die "Import Key not found, use rhimport-create-id to create one\n";

my $ret;
my $log = rhimport::clear_carts($dbh, $group, $to_cart);
my $import_log;
($ret, $import_log) = rhimport::import_single($file, $dropbox, $user, 0, $error_cb);
$log .= $import_log;

$dbh->disconnect();

unlink $file;

if(!$ret) {
  print "\nImport Error:\n";
  print $log;
  exit 1;
}

unlink($STAT_FILE);
open(my $fhs, '>', $STAT_FILE);
print $fhs "$id\n$file";
close($fhs);

unlink($LAST_FILE);
open($fhs, '>', $LAST_FILE);
print $fhs $this_broadcast->iso8601();
close($fhs);

exit 0;