path: root/rhimport

#!/usr/bin/perl -w
#
#
#  rhimport
#
#  Copyright (C) 2009 Christian Pointner <equinox@helsinki.at>
#
#  This file is part of rhimport.
#
#  rhimport is free software: you can redistribute it and/or modify
#  it under the terms of the GNU General Public License as published by
#  the Free Software Foundation, either version 3 of the License, or
#  any later version.
#
#  rhimport is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.
#
#  You should have received a copy of the GNU General Public License
#  along with rhimport. If not, see <http://www.gnu.org/licenses/>.
#

use strict;

use Getopt::Long;
use DBI;
use Gtk2;
use Gtk2::GladeXML;

use lib '/usr/share/perl5/rhimport/';
use rhimport;

my $DBHOST = "airplay";
my $DBUSER = "rivendellro";
my $DBPW = "lldrivenro";
my $DB = "rivendell";
my $HELP = 0;
my $FILE = "";
my $POOL = 0;
my $KEEPCARTS = 0;
my $DROPBOX = "";
my $LISTALLOWED = 0;

GetOptions ("help!" => \$HELP,
            "file=s" => \$FILE,
            "pool!" => \$POOL,
            "keep-carts!" => \$KEEPCARTS,
            "dropbox=s" => \$DROPBOX,
            "list-allowed!" => \$LISTALLOWED,
             ) or die();

if($HELP) {
  print << "EOF";
usage: $0 --file <audio or playlist file> --pool --keep-carts --dropbox <path to dropbox> --list-allowed

When called with no file and/or no dropbox the GUI gets started to select the missing parameters

options:
     -f | --file          the media file or playlist to import
     -p | --pool          pool mode, import media files referneced by playlist
     -k | --keep-carts    in pool mode keep existing carts instead of clearing them before import
     -d | --dropbox       the path to the dropbox to use
     -l | --list-allowed  list allowed dropboxes and exit

EOF
  exit;
}

my $user = `/usr/bin/id -un`;
$user =~ s/\n//;

my $dbh = DBI->connect("DBI:mysql:$DB:$DBHOST","$DBUSER","$DBPW") or die "Database Error: $DBI::errstr";
my @allowed_dbs = rhimport::get_dropboxes($dbh, $user);

if($LISTALLOWED) {
  for my $href ( @allowed_dbs ) {
    print "$href->{'NAME'} \t-> $href->{'PATH'}\n";
  }
  $dbh->disconnect();
  exit 0;
}

###########################################
## GUI mode

my $guixml;

sub set_mode_playlist_gui()
{
  if(!$guixml) {
    print STDERR "no GUI definition found!\n";
    exit 0;
  }
  
  $POOL = 1;
  my $l_mode = $guixml->get_widget('l_mode');
  $l_mode->set_label("<b>Musik Pool</b>");
  my $cb_clear_carts = $guixml->get_widget('cb_clear_carts');
  $cb_clear_carts->set_sensitive(1);
  my $l_file_playlist = $guixml->get_widget('l_file_playlist');
  $l_file_playlist->set_label("<b>Playlist</b>");
  my $filter = Gtk2::FileFilter->new;
  $filter->add_pattern("*.m3u");
  my $filechooser = $guixml->get_widget('filechooser');
  $filechooser->set_filter($filter);
}

sub set_mode_file_gui()
{
  if(!$guixml) {
    print STDERR "no GUI definition found!\n";
    exit 0;
  }
  
  $POOL = 0;
  my $l_mode = $guixml->get_widget('l_mode');
  $l_mode->set_label("<b>Sendung</b>");
  my $cb_clear_carts = $guixml->get_widget('cb_clear_carts');
  $cb_clear_carts->set_sensitive(0);
  my $l_file_playlist = $guixml->get_widget('l_file_playlist');
  $l_file_playlist->set_label("<b>Datei</b>");
  my $filter = Gtk2::FileFilter->new;
  $filter->add_pattern("*");
  my $filechooser = $guixml->get_widget('filechooser');
  $filechooser->set_filter($filter);
}

sub toggle_mode_gui()
{
  if($POOL) {
    set_mode_file_gui();
  } else {
    set_mode_playlist_gui();
  }
}

my $gui_progress_cb = sub {
  my ($elapsed, $max, $text) = @_;

  if(!$guixml) {
    print STDERR "no GUI definition found!\n";
    exit 0;
  }
  my $progressbar = $guixml->get_widget('progressbar');
  $progressbar->set_text("($elapsed/$max) $text");
  $progressbar->set_fraction($elapsed/$max);
  while (Gtk2->events_pending) {
    Gtk2->main_iteration;
  }
  Gtk2::Gdk->flush;
};

sub start_import_gui()
{
  if(!$guixml) {
    print STDERR "no GUI definition found!\n";
    exit 0;
  }

  my $l_status = $guixml->get_widget('l_status');

  my $filechooser = $guixml->get_widget('filechooser');
  my $file = $filechooser->get_filename;
  if(!$file || -d $file) {
    if($POOL) {
      $l_status->set_label("Keine Playlist ausgewhlt!");
    } else {
      $l_status->set_label("Keine Audio Datei ausgewhlt!");
    }
    return 0;
  }
  $filechooser->unselect_all;

  my $co_dropbox = $guixml->get_widget('co_dropbox');
  my $dropbox = $allowed_dbs[$co_dropbox->get_active]->{'PATH'};
  my $group = $allowed_dbs[$co_dropbox->get_active]->{'GROUP'};

  $l_status->set_label("importiere von $file");

  my $ret;
  if($POOL) {
    my $cb_clear_carts = $guixml->get_widget('cb_clear_carts');
    if($cb_clear_carts->get_active) {
      rhimport::clear_carts($dbh, $group);
    }
    $ret = rhimport::import_playlist($file, $dropbox, $gui_progress_cb);
  } else {
    $ret = rhimport::import_single($file, $dropbox, $gui_progress_cb);
  }

  if($ret) {
    $l_status->set_label("Fehler beim Importieren");
  }

  return $ret;
}

sub show_used_carts_gui()
{
  if(!$guixml) {
    print STDERR "no GUI definition found!\n";
    exit 0;
  }

  my $co_dropbox = $guixml->get_widget('co_dropbox');
  my $group = $allowed_dbs[$co_dropbox->get_active]->{'GROUP'};


  my $l_status = $guixml->get_widget('l_status');
  my ($low_cart, $high_cart) = rhimport::get_cart_range($dbh, $group);
  if($low_cart eq $high_cart) {
    $l_status->set_label("Cart: $low_cart");
  } else {
    $l_status->set_label("Carts: $low_cart - $high_cart");
  }

#  my $usedcartswin = $guixml->get_widget('usedcartswin');
#  $usedcartswin or die "can't find Widget";
#  $usedcartswin->resize(640,480);
#  $usedcartswin->show;
}

sub clear_status_gui()
{
  if(!$guixml) {
    print STDERR "no GUI definition found!\n";
    exit 0;
  }

  my $l_status = $guixml->get_widget('l_status');
  $l_status->set_label("");
  
  my $progressbar = $guixml->get_widget('progressbar');
  $progressbar->set_text("");
  $progressbar->set_fraction(0);
}

sub dropbox_updated_gui()
{
  if(!$guixml) {
    print STDERR "no GUI definition found!\n";
    exit 0;
  }

  
}

if(!$FILE || !$DROPBOX) {
  Gtk2->init;

  $guixml = Gtk2::GladeXML->new('rhimport.glade');
  $guixml or die "can't load glade xml file";
  require gui_callbacks;

  my $model = Gtk2::ListStore->new('Glib::String', 'Glib::String', 'Glib::String', 'Glib::String');
  for my $href ( @allowed_dbs ) {
    $model->set ($model->append, 0, $href->{'PATH'}, 1, $href->{'GROUP'}, 2, $href->{'TO_CART'}, 3, $href->{'NAME'});
  }
  my $co_dropbox = $guixml->get_widget('co_dropbox');
  $co_dropbox->set_model($model);
  my $renderer = Gtk2::CellRendererText->new;
  $co_dropbox->pack_start($renderer, 1);
  $co_dropbox->add_attribute($renderer, text => 3);
  $co_dropbox->set_active(0);

  my $cb_clear_carts = $guixml->get_widget('cb_clear_carts');
  if($KEEPCARTS) {
    $cb_clear_carts->set_active(0);
  } else {
    $cb_clear_carts->set_active(1);
  }

  if($POOL) {
    set_mode_playlist_gui();
  } else {
    set_mode_file_gui();
  }

  $guixml->signal_autoconnect_from_package('gui_callbacks');
  my $appwin = $guixml->get_widget('appwin');
  $appwin or die "can't find Main Window";
  $appwin->resize(800,600);
  $appwin->show;
  
  Gtk2->main;
  $dbh->disconnect();
  exit 0;
}

###########################################
## command line mode

(-e "$FILE") or die "file '$FILE' not found";
if($POOL) {
  print "will import from playlist $FILE, with user $user\n\n";
} else {
  print "will import $FILE, with user $user\n\n";
}

my $group = '';
for my $href (@allowed_dbs) {
  if($href->{'PATH'} eq $DROPBOX) {
    $group = $href->{'GROUP'};
  }
}

if($group eq '') {
  print "Dropbox not found or not allowed\n";
  exit 1
}

my $ret;
if($POOL) {
  if(!$KEEPCARTS) {
    rhimport::clear_carts($dbh, $group);
  }

  $ret = rhimport::import_playlist($FILE, $DROPBOX);
} else {
  $ret = rhimport::import_single($FILE, $DROPBOX);
}

$dbh->disconnect();
exit $ret;