#!/usr/bin/perl -w
#
#
#  rhimport
#
#  Copyright (C) 2009 Christian Pointner <equinox@helsinki.at>
#
#  This file is part of rhimport.
#
#  rhimport is free software: you can redistribute it and/or modify
#  it under the terms of the GNU General Public License as published by
#  the Free Software Foundation, either version 3 of the License, or
#  any later version.
#
#  rhimport is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.
#
#  You should have received a copy of the GNU General Public License
#  along with rhimport. If not, see <http://www.gnu.org/licenses/>.
#

use strict;
use DBI;
use Date::Calc;
use XML::Feed;
use XML::Feed::Entry;
use XML::Feed::Content;
use XML::Feed::Enclosure;
use File::Fetch;
use IO::Handle;
use IPC::Open3;

use lib '/usr/local/share/rhimport/';
use rhimport;

my $DBHOST = "airplay";
my $DBUSER = "rivendell";
my $DBPW = "lldriven";
my $DB = "rivendell";

my $STAT_FILE = $ENV{'HOME'} . "/rhimport-dn.stat";
my $RSS_URL = "http://www.democracynow.org/podcast.xml";
my @PV_SCRIPT = ('/usr/bin/ssh', 'root@intranet', 'addnote', '111');

my $user = `/usr/bin/id -un`;
$user =~ s/\n//;
my $group = "democracyn";

my $dbh = DBI->connect("DBI:mysql:$DB:$DBHOST","$DBUSER","$DBPW") or die "Database Error: $DBI::errstr";
my @allowed_dbs = rhimport::get_dropboxes($dbh, $user, $group);


my $dropbox = "";
my $to_cart = 0;

my @today = Date::Calc::Today();
my @yesterday = Date::Calc::Add_Delta_Days($today[0], $today[1], $today[2], -1);

print "today: " . Date::Calc::Date_to_Text(@today) . "\n";
print "yesterday: " . Date::Calc::Date_to_Text(@yesterday) . "\n";


for my $href ( @allowed_dbs ) {
  my $dow = Date::Calc::Day_of_Week(@today);
  if ($dow == int(substr($href->{'NAME'},0,2))) {
    $dropbox = $href->{'PATH'};
    $to_cart = $href->{'TO_CART'};    
  }
}

if($dropbox eq "") {
  print "no dropbox for today\n";
  $dbh->disconnect();
  exit 0;
}

my $y = sprintf("%04d-%02d-%02d", $yesterday[0], $yesterday[1], $yesterday[2]);
print "looking for files from date $y in RSS Feed\n";

my $feed = XML::Feed->parse(URI->new($RSS_URL))
  or die "Error fetching feed: " . XML::Feed->errstr;

my $file = "";
for my $entry ($feed->entries) {
  if($entry->enclosure && $entry->enclosure->type eq "audio/mpeg") {
    my $sum_title = $entry->title;
    my $sum_text = $entry->summary->body . "\n" . $entry->link;

    if($entry->id =~ /tag:democracynow.org,([0-9-]+):media\/mp3download\/[^\/]+/) {
      next if($y ne $1);
  
      my $ff = File::Fetch->new(uri => $entry->enclosure->url);

      my $current_file = `cat $STAT_FILE`;
      if($current_file eq $ff->output_file) {
        print "Already downloaded file of today\n";
        $dbh->disconnect();
        exit 0;
      }
      unlink($STAT_FILE);
      open(my $fhs, '>', $STAT_FILE);
      print $fhs $ff->output_file;
      close($fhs);

      print $1 . ": downloading " . $entry->enclosure->url . " (" . $entry->enclosure->length . " Bytes) .. ";
      $file = $ff->fetch( to => '/tmp' ) or die $ff->error;
      print "ok\n";
      
      print "summary:\n" . $sum_title . "\n\n" . $sum_text . "\n";

      push(@PV_SCRIPT, sprintf("%04d-%02d-%02d", $today[0], $today[1], $today[2]));
      my ($reader, $writer, $error ) = ( new IO::Handle, new IO::Handle, new IO::Handle );
      $writer->autoflush(1);
      local $SIG{CHLD} = 'DEFAULT';
      my $pid = open3($writer, $reader, $error, @PV_SCRIPT);
      print $writer $sum_title . "\n" . $sum_text;
      close $writer;
      waitpid $pid, 0;
      if ( $? >> 8 ) {
        print "\n\nPV: adding note failed\n";
        print "STDERR:\n" . join('', <$error>) . "\n";
        print "STDOUT:\n" . join('', <$reader>) . "\n";
      } else {
        print "\nPV: note added successfully";
        print join('', <$reader>) . "\n";
      }
      print "\n";
    }
  }
}
if($file eq "" || !(-e "$file")) {
  print "No Entry found for today or download error - just clearing cart!\n";
  rhimport::check_key_file() or die "Import Key not found, use rhimport-create-id to create one\n";
  rhimport::clear_carts($dbh, $group, $to_cart);
  exit 1;
}

print "will import $file to dropbox $dropbox (cart=$to_cart)\n\n";

my $error_cb = sub {
  my ($text) = @_;

  print "\n$text";
  return 0;
};

rhimport::check_key_file() or die "Import Key not found, use rhimport-create-id to create one\n";

my $ret;
my $log;
$log = rhimport::clear_carts($dbh, $group, $to_cart);
my $import_log;
($ret, $import_log) = rhimport::import_single($file, $dropbox, $user, 0, $error_cb);
$log .= $import_log;

$dbh->disconnect();

unlink $file;

if(!$ret) {
  print "\nImport Error:\n";
  print $log;
  exit 1;
}

exit 0;