#!/usr/bin/perl -w
#
#
#  rhautoimport
#
#  Copyright (C) 2009-2015 Christian Pointner <equinox@helsinki.at>
#
#  This file is part of rhautoimport.
#
#  rhautoimport is free software: you can redistribute it and/or modify
#  it under the terms of the GNU General Public License as published by
#  the Free Software Foundation, either version 3 of the License, or
#  any later version.
#
#  rhautoimport is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.
#
#  You should have received a copy of the GNU General Public License
#  along with rhautoimport. If not, see <http://www.gnu.org/licenses/>.
#

use strict;
use Date::Calc;
use XML::Feed;
use XML::Feed::Entry;
use XML::Feed::Content;
use XML::Feed::Enclosure;
use File::Fetch;
use IO::Handle;
use IPC::Open3;
use HTML::Entities;
use RHRD::rddb;

use lib '/usr/local/share/rhautoimport/';
use rhautoimport;

my $STAT_FILE = $ENV{'HOME'} . "/rhautoimport-nw.stat";
my $RSS_URL = "http://cba.fro.at/seriesrss/262514?c=Kfs2IoV2Wmd";
$XML::Feed::MULTIPLE_ENCLOSURES=1;
my $PV_ID = '73';

binmode(STDIN, ":utf8");
binmode(STDOUT, ":utf8");
binmode(STDERR, ":utf8");

if($#ARGV >= 0 && $ARGV[0] eq 'last') {
  print "!!!This is the last attempt, there won't be a retry on error!!!\n"
}

my $user = `/usr/bin/id -un`;
$user =~ s/\n//;
my $group = "netwatcher";

my ($dbh, $errorstring) = RHRD::rddb::opendb();
if(!defined $dbh) {
  print "$errorstring\n";
  exit 1;
}
my @allowed_dbs = RHRD::rddb::get_dropboxes($dbh, $user, $group);
if(!defined $allowed_dbs[0] && defined $allowed_dbs[2]) {
  print "$allowed_dbs[2]\n";
  exit 1;
}

if(scalar(@allowed_dbs) != 1) {
  print "found more or less than 1 Dropbox for this group?!\n";
  RHRD::rddb::closedb($dbh);
  exit 1;
}
my $dropbox = $allowed_dbs[0]->{'PATH'};
my $to_cart = $allowed_dbs[0]->{'TO_CART'};

my @today = Date::Calc::Today();
my @import_date = @today;
if( Date::Calc::Day_of_Week(@today) > 3 ) {
  @import_date = Date::Calc::Add_Delta_Days(@import_date, 7);
}
if( Date::Calc::Day_of_Week(@today) != 3 ) {
  @import_date = Date::Calc::Standard_to_Business(@import_date);
  $import_date[2] = 3;
  @import_date = Date::Calc::Business_to_Standard(@import_date);
}
my @broadcast_day = Date::Calc::Add_Delta_Days(@import_date, -5);
print "day of original broadcast: " . Date::Calc::Date_to_Text(@broadcast_day) . "\n";
print "day of Radio Helsinki broadcast: " . Date::Calc::Date_to_Text(@import_date) . "\n";

my $id = sprintf("%04d-%02d-%02d", @import_date);
my $bd = sprintf("%04d-%02d-%02d", @broadcast_day);
my $bdfile = sprintf("NETWATCHER%04d%02d%02d(.*)\.MP3", @broadcast_day);
print "looking for files from $bd in RSS Feed\n";
print " -> $RSS_URL\n";

my $feed = XML::Feed->parse(URI->new($RSS_URL))
  or die "Error fetching feed: " . XML::Feed->errstr;

my $file = "";
my $out_file = "";
my $i = 0;
for my $entry ($feed->entries) {
  $i++;
  next unless $entry->enclosure;
  my $j = 0;
  for my $enclosure($entry->enclosure) {
    $j++;
    if($enclosure->type eq "audio/mpeg" || $enclosure->type eq "audio/ogg") {
      print "$i/$j: (" . $enclosure->type . ", " . $enclosure->length . ") "  . $enclosure->url . "\n";
      my $url = $enclosure->url;
      if($url =~ /^(.*)_cut(\.[^\.]+)$/) {
        $url = $1 . $2;
      }

      my $ff = File::Fetch->new(uri => $url);
      next unless (uc($ff->output_file) =~ $bdfile); # file not from correct day

      my $sum_title = decode_entities($entry->title);
      my $sum_text = decode_entities($entry->content->body);

      my $current_file = `cat $STAT_FILE`;
      if($current_file eq $ff->output_file) {
        print "Already downloaded file of today\n";
        RHRD::rddb::closedb($dbh);
        exit 0;
      }
      $out_file = $ff->output_file;
      if(!rhautoimport::check_file_extension($out_file)) {
        print "\n\nThe extension of the matching file '". $out_file . "' seems to be wrong - manual import necessary!!!\n";
        RHRD::rddb::closedb($dbh);
        exit 1;
      }

      print " --> " . $bdfile . ": downloading " . $url . " (" . $enclosure->length . " Bytes) .. ";
      $file = $ff->fetch( to => '/tmp' ) or die $ff->error;
      print "ok\n";

      print "summary:\n" . $sum_title . "\n\n" . $sum_text . "\n";

      rhautoimport::pv_add_note($sum_title, $sum_text, $PV_ID, $id, "1");
      print "\n";

      last;
    }
  }
  last if $file ne "";
}

if($file eq "" || !(-e "$file")) {
  print "No Entry found from $bd or download error - ";
  if($#ARGV >= 0 && $ARGV[0] eq 'last') {
    print "giving up, manual import necessary!!!\n";
  } else {
    print "will retry later\n";
  }
  exit 1;
}

print "will import $file to dropbox $dropbox (cart=$to_cart)\n";

my $error_cb = sub {
  my ($text) = @_;

  print "\n$text";
  return 0;
};

rhautoimport::check_key_file() or die "Import Key not found, use rhautoimport-create-id to create one\n";

my $ret;
my $log = rhautoimport::clear_carts($dbh, $group, $to_cart);
my $import_log;
($ret, $import_log) = rhautoimport::import_single($file, $dropbox, $user, 0, $error_cb);
$log .= $import_log;

RHRD::rddb::closedb($dbh);

unlink $file;

if(!$ret) {
  print "\nImport Error:\n";
  print $log;
  exit 1;
}

unlink($STAT_FILE);
open(my $fhs, '>', $STAT_FILE);
print $fhs $out_file;
close($fhs);

exit 0;