#!/usr/bin/perl -w
#
#
#  rhautoimport
#
#  Copyright (C) 2009-2015 Christian Pointner <equinox@helsinki.at>
#
#  This file is part of rhautoimport.
#
#  rhautoimport is free software: you can redistribute it and/or modify
#  it under the terms of the GNU General Public License as published by
#  the Free Software Foundation, either version 3 of the License, or
#  any later version.
#
#  rhautoimport is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.
#
#  You should have received a copy of the GNU General Public License
#  along with rhautoimport. If not, see <http://www.gnu.org/licenses/>.
#

use strict;
use Date::Calc;
use Time::localtime;
use XML::Feed;
use XML::Feed::Entry;
use XML::Feed::Content;
use XML::Feed::Enclosure;
use URI::URL;
use IO::Handle;
use IPC::Open3;
use RHRD::rddb;

use lib '/usr/local/share/rhautoimport/';
use rhautoimport;

my $STAT_FILE = $ENV{'HOME'} . "/rhautoimport-dn.stat";
my $FILES_RSS_URL = "http://www.democracynow.org/podcast-stations.xml";
my $HEADLINES_RSS_URL = "http://www.democracynow.org/podcast.xml";
my $IGNORE_HEADLINE = 0;
my $PV_ID = '111';

binmode(STDIN, ":utf8");
binmode(STDOUT, ":utf8");
binmode(STDERR, ":utf8");

if($#ARGV >= 0 && $ARGV[0] eq 'last') {
  print "!!!This is the last attempt, there won't be a retry on error!!!\n"
}

if($#ARGV >= 0 && $ARGV[0] eq 'noheadline') {
  $IGNORE_HEADLINE = 1;
  $STAT_FILE = $ENV{'HOME'} . "/rhautoimport-dn-noheadline.stat";
}

my $user = `/usr/bin/id -un`;
$user =~ s/\n//;
my $group = "democracyn";

my ($dbh, $errorstring) = RHRD::rddb::opendb();
if(!defined $dbh) {
  print "$errorstring\n";
  exit 1;
}
my @allowed_dbs = RHRD::rddb::get_dropboxes($dbh, $user, $group);
if(!defined $allowed_dbs[0] && defined $allowed_dbs[2]) {
  print "$allowed_dbs[2]\n";
  exit 1;
}

my $dropbox = "";
my $to_cart = 0;

my @today = Date::Calc::Today();
my @yesterday = Date::Calc::Add_Delta_Days($today[0], $today[1], $today[2], -1);
my @tomorrow = Date::Calc::Add_Delta_Days($today[0], $today[1], $today[2], 1);

my @broadcast_day = @yesterday;
my @import_day = @today;
if(localtime->hour >= 12) {
  print "It's past noon, assuming to import file from today\n";
  @broadcast_day = @today;
  @import_day = @tomorrow;
}

print "day of original broadcast: " . Date::Calc::Date_to_Text(@broadcast_day) . "\n";
print "day of Radio Helsinki broadcast: " . Date::Calc::Date_to_Text(@import_day) . "\n";

for my $href ( @allowed_dbs ) {
  my $dow = Date::Calc::Day_of_Week(@import_day);
  if ($dow == int(substr($href->{'NAME'},0,2))) {
    $dropbox = $href->{'PATH'};
    $to_cart = $href->{'TO_CART'};
  }
}

if($dropbox eq "") {
  print "no dropbox for day in question\n";
  RHRD::rddb::closedb($dbh);
  exit 0;
}

my $y = sprintf("%04d-%02d-%02d", $broadcast_day[0], $broadcast_day[1], $broadcast_day[2]);
my $yc = sprintf("%04d-%02d%02d", $broadcast_day[0], $broadcast_day[1], $broadcast_day[2]);

print "looking for files from date $y in RSS Feed\n";
print " -> $FILES_RSS_URL\n";

my $files_feed = XML::Feed->parse(URI->new($FILES_RSS_URL))
  or die "Error fetching feed: " . XML::Feed->errstr;

my $file = "";
my $out_file = "";
for my $entry ($files_feed->entries) {
  if($entry->enclosure && $entry->enclosure->type eq "audio/mpeg") {
    if($entry->enclosure->url =~ /^https?:\/\/.*\.democracynow\.org\/dn([0-9-]+)-1\.mp3$/) {
      next if($yc ne $1);

      my $url = new URI::URL($entry->enclosure->url);
      my @path = $url->path_components;

      my $current_file = `cat $STAT_FILE`;
      if($current_file eq $path[-1]) {
        print "Already downloaded file of day in question\n";
        RHRD::rddb::closedb($dbh);
        exit 0;
      }
      $out_file = $path[-1];
      if(!rhautoimport::check_file_extension($out_file)) {
        print "\n\nThe extension of the matching file '". $out_file . "' seems to be wrong - manual import necessary!!!\n";
        RHRD::rddb::closedb($dbh);
        exit 1;
      }

      print $1 . ": downloading " . $entry->enclosure->url . " (" . $entry->enclosure->length . " Bytes) .. ";

      $file = "/tmp/" . $out_file;
      system("wget", "--quiet", "--no-check-certificate", $url, "-O", $file);
      if( $! != 0) {
        die "wget returned with error: " . $!;
      }
      print "ok\n";

      last;
    }
  }
}
if($file eq "" || !(-e "$file")) {
  print "No Entry found from day in qeustion or download error - ";
  if($#ARGV >= 0 && $ARGV[0] eq 'last') {
    print "giving up, manual import necessary!!!\n";
  } else {
    print "will retry later\n";
  }
  exit 1;
}


unless($IGNORE_HEADLINE) {
  print "\nlooking for headlines from date $y in RSS Feed\n";
  print " -> $HEADLINES_RSS_URL\n";

  my $headlines_feed = XML::Feed->parse(URI->new($HEADLINES_RSS_URL))
    or die "Error fetching feed: " . XML::Feed->errstr;

  for my $entry ($headlines_feed->entries) {
    if($entry->enclosure && $entry->enclosure->type eq "audio/mpeg") {
      my $sum_title = $entry->title;
      my $sum_text = $entry->summary->body . "\n<br />\n<a href=\"" . $entry->link . "\">" . $entry->link . "</a>\n";

      if($entry->id =~ /tag:democracynow.org,([0-9-]+):media\/mp3download\/[^\/]+/) {
        next if($y ne $1);

        print "summary:\n" . $sum_title . "\n\n" . $sum_text . "\n";
        rhautoimport::pv_add_note($sum_title, $sum_text, $PV_ID, sprintf("%04d-%02d-%02d", @import_day), "1", 0);
        print "\n";
        rhautoimport::pv_add_note($sum_title, $sum_text, $PV_ID, sprintf("%04d-%02d-%02d", @import_day), "1", 1);
        print "\n";

        last;
      }
    }
  }
} else {
  print "\nignoring headlines for they are not available by now\n";
  my $dow_string = Date::Calc::Day_of_Week_to_Text(Date::Calc::Day_of_Week(@broadcast_day));
  my $sum_title = sprintf("Democracy Now! %04d-%02d-%02d %s", @broadcast_day, $dow_string);
  my $sum_text = "";
  print "summary:\n" . $sum_title . "\n\n" . $sum_text . "\n";
  rhautoimport::pv_add_note($sum_title, $sum_text, $PV_ID, sprintf("%04d-%02d-%02d", @broadcast_day), "1", 2);
  print "\n";
}

print "converting $file ... ";
my $infile = $file;
$file =~ s/\.mp3$/.wav/;
system("ffmpeg", "-i", $infile, "-acodec", "pcm_s16le", $file);
if( $! != 0) {
  die "ffmpeg returned with error: " . $!;
}
print "ok\n";
unlink $infile;

print "will import $file to dropbox $dropbox (cart=$to_cart)\n\n";

my $error_cb = sub {
  my ($text) = @_;

  print "\n$text";
  return 0;
};

rhautoimport::check_key_file() or die "Import Key not found, use rhautoimport-create-id to create one\n";

my $ret;
my $log;
$log = rhautoimport::clear_carts($dbh, $group, $to_cart);
my $import_log;
($ret, $import_log) = rhautoimport::import_single($file, $dropbox, $user, 0, $error_cb);
$log .= $import_log;

RHRD::rddb::closedb($dbh);

unlink $file;

if(!$ret) {
  print "\nImport Error:\n";
  print $log;
  exit 1;
}

unlink($STAT_FILE);
open(my $fhs, '>', $STAT_FILE);
print $fhs $out_file;
close($fhs);

exit 0;