#!/usr/bin/perl -w
#
#
#  rhautoimport
#
#  Copyright (C) 2009-2017 Christian Pointner <equinox@helsinki.at>
#
#  This file is part of rhautoimport.
#
#  rhautoimport is free software: you can redistribute it and/or modify
#  it under the terms of the GNU General Public License as published by
#  the Free Software Foundation, either version 3 of the License, or
#  any later version.
#
#  rhautoimport is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.
#
#  You should have received a copy of the GNU General Public License
#  along with rhautoimport. If not, see <http://www.gnu.org/licenses/>.
#

use strict;
use Date::Calc;
use Time::localtime;
use XML::Feed;
use XML::Feed::Entry;
use XML::Feed::Content;
use XML::Feed::Enclosure;
use URI::URL;

use lib '/usr/local/share/rhautoimport/';
use rhautoimport;

my $STAT_FILE = $ENV{'HOME'} . "/rhautoimport-dn.stat";
my $FILES_RSS_URL = "https://www.democracynow.org/podcast-stations.xml";
my $HEADLINES_RSS_URL = "http://www.democracynow.org/podcast.xml";
my $RD_GROUP = "democracyn";
my $PV_ID = '111';
my $TITLE="Democracy Now!";
my $LAST_RUN = 0;

binmode(STDIN, ":utf8");
binmode(STDOUT, ":utf8");
binmode(STDERR, ":utf8");

if($#ARGV >= 0 && $ARGV[0] eq 'last') {
  print "!!!This is the last attempt, there won't be a retry on error!!!\n";
  $LAST_RUN = 1;
}
rhautoimport::report_title_and_last($TITLE, $LAST_RUN);


my @today = Date::Calc::Today();
my @yesterday = Date::Calc::Add_Delta_Days(@today, -1);
my @tomorrow = Date::Calc::Add_Delta_Days(@today, 1);

my @broadcast_day = @yesterday;
my @import_day = @today;
if(localtime->hour >= 12) {
  print "It's past noon, assuming to import file from today\n";
  @broadcast_day = @today;
  @import_day = @tomorrow;
}
my $dow = Date::Calc::Day_of_Week(@import_day);
$dow = 0 unless $dow < 7;

print "day of original broadcast: " . Date::Calc::Date_to_Text(@broadcast_day) . "\n";
print "day of Radio Helsinki broadcast: " . Date::Calc::Date_to_Text(@import_day) . "\n";

my $show_id = -1;
my $show_title = "";

my @allowed_dbs = rhautoimport::get_dropboxes($RD_GROUP);
if(!defined $allowed_dbs[0] && defined $allowed_dbs[1]) {
  print "$allowed_dbs[1]\n";
  exit 1;
}

for my $href ( @allowed_dbs ) {
  if($dow == $href->{'SHOWDOW'}) {
    $show_title = $href->{'SHOWTITLE'};
    $show_id = $href->{'SHOWID'};
    last;
  }
}

if($show_id < 0) {
  print "no dropbox for day in question\n";
  exit 42;
}

my $y = sprintf("%04d-%02d-%02d", @broadcast_day);
my $yc = sprintf("%04d-%02d%02d", @broadcast_day);

print "looking for files from date $y in RSS Feed\n";
print " -> $FILES_RSS_URL\n";

my ($result, $files_feed) = rhautoimport::fetch_parse_rss($FILES_RSS_URL);
unless ($result) {
  print "Error fetching feed: $files_feed\n";
  exit 1;
}

my $uri = "";
my $file = "";
my $sum_title = "";
my $sum_text = "";

for my $entry ($files_feed->entries) {
  if($entry->enclosure && $entry->enclosure->type eq "audio/mpeg") {
    if($entry->enclosure->url =~ /^https?:\/\/.*\.democracynow\.org\/dn([0-9-]+)-1\.mp3$/) {
      next if($yc ne $1);

      $uri = new URI::URL($entry->enclosure->url);
      my @path = $uri->path_components;

      my $current_file = `cat $STAT_FILE`;
      if($current_file eq $path[-1]) {
        print "Already downloaded file of day in question\n";
        exit 42;
      }
      $file = $path[-1];
      if(!rhautoimport::check_file_extension($file)) {
        print "\n\nThe extension of the matching file '". $file . "' seems to be wrong - manual import necessary!!!\n";
        print "\n\n --> https://import.helsinki.at/shows/$show_id\n";
        exit 1;
      }

      last;
    }
  }
}
if($uri eq "") {
  print "No Entry found from day in question - ";
  if($LAST_RUN) {
    print "giving up, manual import necessary!!!\n";
    print "\n\n --> https://import.helsinki.at/shows/$show_id\n";
  } else {
    print "will retry later\n";
  }
  exit 1;
}


print "\nlooking for headlines from date $y in RSS Feed\n";
print " -> $HEADLINES_RSS_URL\n";


($result, my $headlines_feed) = rhautoimport::fetch_parse_rss($HEADLINES_RSS_URL);
unless ($result) {
  print "Error fetching feed: $headlines_feed\n";
  exit 1;
}

for my $entry ($headlines_feed->entries) {
  if($entry->enclosure && $entry->enclosure->type eq "audio/mpeg") {
    $sum_title = $entry->title;
    $sum_text = $entry->summary->body . "\n<br />\n<a href=\"" . $entry->link . "\">" . $entry->link . "</a>\n";

    if($entry->id =~ /tag:democracynow.org,([0-9-]+):media\/mp3podcast\/[^\/]+/) {
      next if($y ne $1);

      print "summary:\n" . $sum_title . "\n\n" . $sum_text . "\n";
      last;
    }
  }
}

print "\n\nwill import '$uri' to show $show_id, $show_title\n\n";

my $exit_code = 0;
my ($ret, $log) = rhautoimport::import_uri($show_id, $uri->as_string);
if($ret) {
  print "\nImport Error:\n\n";
  print $log;
  print "\n\nNot adding PV note!!";
  exit 1;
}
print "\nImport Success:\n\n";
print $log;
if($sum_title ne "") {
  print "\n";
  ($ret, $log) = rhautoimport::pv_add_note($sum_title, $sum_text, $PV_ID, sprintf("%04d-%02d-%02d", @import_day), "1", 0);
  print $log;
  if($ret) {
    print "\nIgnoring failed note import - manual intervention necessary!\n";
    $exit_code = 23;
  }
} else {
  print "\nIgnoring missing note - manual intervention necessary!\n";
  $exit_code = 23;
}

unlink($STAT_FILE);
open(my $fhs, '>', $STAT_FILE);
print $fhs $file;
close($fhs);

exit $exit_code;