#!/usr/bin/perl -w
#
#
#  rhautoimport
#
#  Copyright (C) 2009-2017 Christian Pointner <equinox@helsinki.at>
#
#  This file is part of rhautoimport.
#
#  rhautoimport is free software: you can redistribute it and/or modify
#  it under the terms of the GNU General Public License as published by
#  the Free Software Foundation, either version 3 of the License, or
#  any later version.
#
#  rhautoimport is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.
#
#  You should have received a copy of the GNU General Public License
#  along with rhautoimport. If not, see <http://www.gnu.org/licenses/>.
#

use strict;
use Date::Calc;
use DateTime::Format::Strptime;
use XML::Feed;
use XML::Feed::Entry;
use XML::Feed::Content;
use XML::Feed::Enclosure;
use URI::URL;
use HTML::Entities;
use RHRD::utils;

use lib '/usr/local/share/rhautoimport/';
use rhautoimport;

my $STAT_FILE = $ENV{'HOME'} . "/rhautoimport-btl.stat";
my $RSS_URL = "http://www.btlonline.org/rss/btl128.xml";
my $RD_GROUP = "betweenlin";
my $PV_ID = '221';
my $TITLE="Between the Lines";
my $LAST_RUN = 0;
my $upload_delay_days = 0;   # files are usally there on the same day

binmode(STDIN, ":utf8");
binmode(STDOUT, ":utf8");
binmode(STDERR, ":utf8");

my $curweek = RHRD::utils::get_rd_week();
if($curweek == 2 || $curweek == 4) {
  print "won't do anything in week 2 or 4!\n";
  rhautoimport::report_title_and_last($TITLE, 0);
  exit 42;
}

if($#ARGV >= 0 && $ARGV[0] eq 'last') {
  print "!!!This is the last attempt, there won't be a retry on error!!!\n";
  $LAST_RUN = 1;
}
rhautoimport::report_title_and_last($TITLE, $LAST_RUN);


my @allowed_dbs = rhautoimport::get_dropboxes($RD_GROUP);
if(!defined $allowed_dbs[0] && defined $allowed_dbs[1]) {
  print "$allowed_dbs[1]\n";
  exit 1;
}

if(scalar(@allowed_dbs) != 1) {
  print "found more or less than one Dropbox for this group?!\n";
  exit 1;
}
my $show_id = $allowed_dbs[0]->{'SHOWID'};
my $show_title = $allowed_dbs[0]->{'SHOWTITLE'};

my @today = Date::Calc::Today();
my @import_date = Date::Calc::Add_Delta_Days(@today, 7);
@import_date = Date::Calc::Standard_to_Business(@import_date);
$import_date[2] = 1;
@import_date = Date::Calc::Business_to_Standard(@import_date);

my @broadcast_date = Date::Calc::Add_Delta_Days(@import_date, -5);

print "today: " . Date::Calc::Date_to_Text(@today) . "\n";
print "day of next Radio Helsinki broadcast: " . Date::Calc::Date_to_Text(@import_date) . "\n";
print "current broadcast cycle starts/started on: " . Date::Calc::Date_to_Text(@broadcast_date) . "\n";

if(Date::Calc::Delta_Days(@broadcast_date, @today) <= $upload_delay_days) {
  print "File won't be available by now!\n";
  exit 42;
}

my $id = sprintf("%04d-%02d-%02d", @import_date);
my $bd = sprintf("%04d-%02d-%02d", @broadcast_date);
my $bdfile = ".*broadcast-affiliates?.*\.mp3";

print "looking for files issued on '$bd' and named like '$bdfile' in RSS Feed\n";
print " -> $RSS_URL\n";

my ($result, $feed) = rhautoimport::fetch_parse_rss($RSS_URL);
unless ($result) {
  print "Error fetching feed: $feed\n";
  exit 1;
}

my $uri = "";
my $file = "";
my $sum_title = "";
my $sum_text = "";

for my $entry ($feed->entries) {
  if($entry->enclosure && ($entry->enclosure->type eq "audio/mpeg" || entry->enclosure->type eq "audio/mp3")) {
    next unless $entry->enclosure->url =~ /$bdfile/;

    my $idt = DateTime::Format::Strptime::strptime("%Y-%m-%dT%H:%M:%S", $entry->issued);
    next unless($broadcast_date[0] == $idt->year && $broadcast_date[1] == $idt->month && $broadcast_date[2] == $idt->day);

    $uri = new URI::URL($entry->enclosure->url);
    my @path = $uri->path_components;
    $file = $path[-1];

    my $current_file = `cat $STAT_FILE`;
    if($current_file eq $file) {
      print "Already downloaded file of today\n";
      exit 42;
    }
    if(!rhautoimport::check_file_extension($file)) {
      print "\n\nThe extension of the matching file '". $file . "' seems to be wrong - manual import necessary!!!\n";
      print "\n\n --> https://import.helsinki.at/shows/$show_id\n";
      exit 1;
    }

    $sum_title = decode_entities($entry->title);
    $sum_title =~ s/ \(128 kbps\)$//;
    $sum_title =~ s/ \(broadcast affiliate version\)//;
    $sum_text = decode_entities($entry->content->body);
    print "summary:\n" . $sum_title . "\n\n" . $sum_text . "\n";
    last;
  }
}
if($uri eq "") {
  print "No Entry found for " . Date::Calc::Date_to_Text(@broadcast_date) . " - ";
  if($LAST_RUN) {
    print "giving up, manual import necessary!!!\n";
    print "\n\n --> https://import.helsinki.at/shows/$show_id\n";
  } else {
    print "will retry later\n";
  }
  exit 1;
}

print "\n\nwill import '$uri' to show $show_id, $show_title\n\n";

my ($ret, $log) = rhautoimport::import_uri($show_id, $uri->as_string);
if($ret) {
  print "\nImport Error:\n\n";
  print $log;
  print "\n\nNot adding PV note!!";
  exit 1;
}
print "\nImport Success:\n\n";
print $log;
print "\n";
my $exit_code = 0;
($ret, $log) = rhautoimport::pv_add_note($sum_title, $sum_text, $PV_ID, $id, "1");
print $log;
if($ret) {
  print "\nIgnoring failed note import - manual intervention necessary!\n";
  $exit_code = 23;
}

unlink($STAT_FILE);
open(my $fhs, '>', $STAT_FILE);
print $fhs "$file";
close($fhs);

exit $exit_code;